Eamon 075 - Temple of the Guild
Emulation Item Preview
Share or Embed This Item
Notes
Disk info for Eamon_075_Temple_of_the_Guild_1991_Doumakes_D..do:
File Name: a2_Eamon_075_Temple_of_the_Guild_1991_Doumakes_D./Eamon_075_Temple_of_the_Guild_1991_Doumakes_D..do
Disk Name: DISK VOLUME #254
Physical Size (bytes): 143360
Free Space (bytes): 64768
Used Space (bytes): 78592
Physical Size (KB): 140
Free Space (KB): 63
Used Space (KB): 76
Archive Order: DOS
Disk Format: DOS 3.3
Total Sectors: 560
Free Sectors: 253
Used Sectors: 307
Tracks On Disk: 35
Sectors On Disk: 16
Disk directory for Eamon_075_Temple_of_the_Guild_1991_Doumakes_D..do:
a2_Eamon_075_Temple_of_the_Guild_1991_Doumakes_D./Eamon_075_Temple_of_the_Guild_1991_Doumakes_D..do DISK VOLUME #254
* A 005 EAMON ADVENTURE #75
A 010 TEMPLE OF THE GUILD
T 001 LAST UPDATE: ?
T 002 EAMON.NAME
T 006 EAMON.ROOMS
T 006 EAMON.ROOM NAMES
T 011 EAMON.MONSTERS
T 012 EAMON.ARTIFACTS
T 062 EAMON.DESC
A 019 SHEEPSKINNER CASINO
A 013 GLADIATOR POOL
A 059 MAIN PROGRAM
A 011 PROVING GROUNDS
A 008 LOBBY
A 016 BUREAU OF NAMES
T 002 PRIZE
DOS 3.3 format; 64,768 bytes free; 78,592 bytes used.
Text found in Eamon_075_Temple_of_the_Guild_1991_Doumakes_D..do/BUREAU OF NAMES.bas:
10 REM BUREAU OF NAMES
15 D$ = CHR$(4)
20 HOME
25 INVERSE
30 HTAB 12: PRINT "BUREAU OF NAMES"
35 NORMAL
40 PRINT
50 PRINT " YOU ARE STANDING BEFORE A HIGH- RANKING CLERIC EMPLOYED BY THE GUILD. HE ASKS IF YOU WISH TO:"
60 PRINT
70 PRINT "1. CHANGE YOUR NAME?"
80 PRINT "2. CHANGE THE NAME OF A WEAPON?"
90 PRINT "3. CHANGE YOUR MIND (AND LEAVE)?"
100 PRINT
110 PRINT "HIT KEY FOR CHOICE (1-3): ";
120 GET R$: IF R$ <"1" OR R$ >"3" GOTO 120
130 PRINT
140 ON VAL(R$) GOTO 150,540,1500
150 PRINT
160 PRINT "'SO, YOU WISH TO CHANGE YOUR LEGAL NAME,EH? WELL, THIS KIND OF THING IS NOT TO BE DONE LIGHTLY. THERE WILL BE A FEE OF100 GOLD PIECES, FOR STARTERS, JUST TO MAKE SURE YOU'RE IN EARNEST. AND THEN"
170 PRINT "YOUR NEW NAME HAS TO BE APPROVED BY THE BOARD OF JUDGES. STILL INTERESTED?' (HIT Y OR N) "
180 GET R$: IF R$ < >"Y" AND R$ < >"N" GOTO 180
190 PRINT
200 IF R$ = "N" THEN PRINT "WELL, GOOD DAY THEN.": PRINT D$"RUN LOBBY"
210 GOSUB 2000
220 IF GOLD +BANK <100 THEN : PRINT "'YOU DON'T HAVE ENOUGH MONEY! BEGONE AT ONCE!'": PRINT D$"RUN LOBBY"
230 IF GOLD > = 100 THEN GOLD = GOLD -100: GOTO 270
240 PRINT "'WE SHALL HAVE TO TRANSFER A LITTLE GOLDFROM YOUR BANK ACCOUNT TO PAY FOR THIS,'HE SAYS. 'NO PROBLEM.' BEFORE YOU CAN"
250 PRINT "OBJECT, HE STAMPS AN IMPORTANT-LOOKING FORM WITH AN IMPORTANT-LOOKING RUBBER STAMP AND HANDS THE FORM TO A PAGE. THEPAGE LEAVES IMMEDIATELY FOR THE BANK."
260 BANK = BANK -100 +GOLD:GOLD = 0
270 PRINT
280 PRINT "'SO, YOU DON'T WANT TO BE CALLED BY THE NAME OF ";NA$;" ANYMORE.'"
290 INPUT "'WHAT WOULD YOU RATHER BE CALLED?' ";NA$
300 PRINT "'VERY WELL, I'LL HAVE TO CHECK WITH THE BOARD OF JUDGES. PLEASE WAIT HERE.' HELEAVES THE ROOM."
310 PRINT
320 PRINT "(INSERT EAMON MASTER DISK AND HIT A KEY)"
330 GET R$: PRINT
340 ONERR GOTO 370
350 PRINT D$"VERIFY EAMON.PIC"
360 GOTO 390
370 IF PEEK(222) = 5 THEN : POKE 216,0: GOTO 310
380 STOP
390 POKE 216,0
400 NO = 0
410 PRINT D$"OPEN CHARACTERS,L150"
420 I = 1
425 ONERR GOTO 465
430 IF I = REC GOTO 462
440 PRINT D$"READ CHARACTERS,R";I
450 INPUT N2$
460 IF NA$ = N2$ THEN NO = 1: GOTO 470
462 I = I +1: GOTO 430
465 IF PEEK(222) < >5 THEN STOP
470 POKE 216,0
480 PRINT D$"CLOSE"
490 IF (NO) THEN PRINT "HE RETURNS AND SAYS, 'THE BOARD REFUSES TO APPROVE THIS NAME CHANGE BECAUSE SOMEOTHER ADVENTURER IS USING THE NEW NAME.'": GOTO 290
500 PRINT "HE RETURNS AND SAYS, 'THE BOARD HAS APPROVED THIS NAME CHANGE. GOOD LUCK, ";NA$
510 ERR = 0: GOSUB 3000
520 PRINT "(HIT ANY KEY TO CONTINUE.) ";: GET R$: PRINT : GOTO 20
530 REM CHANGE NAME OF A WEAPON
540 GOSUB 2000
550 IF WN$(1) = "NONE" THEN PRINT "'YOU AREN'T CARRYING ANY WEAPONS!'": GOTO 40
560 PRINT "'THIS IS A SMALL MATTER. WE CAN TAKE CARE OF IT FOR FREE. WHICH OF YOUR WEAPONS DO YOU WANT TO RENAME?'"
570 I = 2
580 IF WN$(I) < >"NONE" THEN I = I +1: IF I < = 4 GOTO 580
590 NW = I -1
600 INPUT "(TYPE THE WEAPON NAME NOW) ";Z$
610 I = 1
620 IF WN$(I) = Z$ GOTO 650
630 I = I +1: IF I < = 4 GOTO 620
640 PRINT "'YOU AREN'T CARRYING A WEAPON BY THAT NAME! YOUR WEAPONS ARE:": FOR I = 1 TO NW: HTAB 10: PRINT WN$(I): NEXT : PRINT "TRY AGAIN!'": GOTO 600
650 PRINT : INPUT "'AND WHAT WOULD YOU RATHER CALL THIS WEAPON?' ";Z$
660 J = 1
670 IF WN$(J) = Z$ THEN PRINT "'BUT YOU ALREADY HAVE ANOTHER WEAPON BY THAT NAME! YOU CANNOT USE THIS AS A NEWNAME.": GOTO 650
680 J = J +1: IF J < = 4 GOTO 670
690 WN$(I) = Z$
700 PRINT "'VERY WELL. IT'S DONE. FROM NOW ON ITSNAME IS ";WN$(I);"."
710 ERR = 0: GOSUB 3000
720 PRINT "(HIT ANY KEY TO CONTINUE.) ";: GET R$: PRINT : GOTO 20
1490 REM EXIT PROGRAM
1500 PRINT D$"RUN LOBBY"
1999 REM READ-CHARACTER SUBROUTINE
2000 PRINT D$"OPEN FRESH MEAT"
2010 PRINT D$"READ FRESH MEAT"
2020 INPUT REC
2030 INPUT NA$,HD,AG,CH
2040 FOR I = 1 TO 4: INPUT SA%(I): NEXT
2050 FOR I = 1 TO 5: INPUT WA%(I): NEXT
2060 INPUT AE,SEX$,GOLD,BANK,AC
2070 FOR I = 1 TO 4
2080 INPUT WN$(I)
2090 FOR J = 1 TO 4: INPUT WE%(I,J): NEXT
2100 NEXT
2110 PRINT D$"CLOSE"
2120 RETURN
2999 REM WRITE-CHARACTER SUBROUTINE
3000 PRINT : PRINT "(INSERT DISK FOR 'TEMPLE OF THE GUILD' AND PRESS ANY KEY) ";
3005 GET R$: PRINT
3010 ONERR GOTO 3040
3020 PRINT D$"VERIFY TEMPLE OF THE GUILD"
3025 POKE 216,0: GOTO 3050
3040 POKE 216,0: IF PEEK(222) < >6 THEN STOP
3042 ERR = 1
3045 GOTO 3000
3050 PRINT D$"OPEN FRESH MEAT"
3060 PRINT D$"WRITE FRESH MEAT"
3070 PRINT REC
3080 PRINT NA$: PRINT HD: PRINT AG: PRINT CH
3090 FOR I = 1 TO 4: PRINT SA%(I): NEXT
3100 FOR I = 1 TO 5: PRINT WA%(I): NEXT
3110 PRINT AE: PRINT SEX$: PRINT GOLD: PRINT BANK: PRINT AC
3120 FOR I = 1 TO 4
3130 PRINT WN$(I)
3140 FOR J = 1 TO 4: PRINT WE%(I,J): NEXT
3150 NEXT
3160 PRINT D$"CLOSE"
3165 IF ERR GOTO 230
3170 RETURN
Text found in Eamon_075_Temple_of_the_Guild_1991_Doumakes_D..do/EAMON.MONSTERS.txt:
COLOSSUS
23
20
0
100
0
10000
10
5
0
80
1
4
GORGON II
20
20
0
100
0
1000
5
4
0
75
1
4
GORGON I
17
18
0
100
0
700
5
3
0
75
1
4
MAYHEM 3
16
14
0
100
0
500
0
2
0
60
1
4
SARGON
15
13
0
100
0
400
0
1
0
60
1
4
MEDUSA
10
11
0
100
0
300
0
1
0
50
1
4
OTIS
10
10
0
100
0
100
0
1
0
50
1
4
RAT
2
10
0
50
7
5
0
1
0
40
1
4
RAT
2
10
0
50
7
5
0
1
0
40
1
4
RAT
2
10
0
50
7
5
0
1
0
40
1
4
RAT
2
10
0
50
7
5
0
1
0
40
1
4
ORC
3
12
0
50
9
150
0
1
19
40
1
4
ORC
3
12
0
50
9
150
0
1
20
40
1
4
DEMON
15
10
0
80
16
100
0
1
0
50
1
4
DEMON
15
10
0
80
16
100
0
1
0
50
1
4
4
DEMON
15
10
0
80
16
100
0
1
0
50
1
4
KNIGHT
10
10
100
13
150
150
0
1
21
60
1
4
THE OTHER
1
1
0
100
19
150
0
0
0
0
1
1
Text found in Eamon_075_Temple_of_the_Guild_1991_Doumakes_D..do/EAMON.NAME.txt:
TEMPLE OF THE GUILD
6
Text found in Eamon_075_Temple_of_the_Guild_1991_Doumakes_D..do/EAMON.ROOM NAMES.txt:
IN THE ARENA.
AT THE BOTTOM OF A SHAFT.
IN AN EAST-WEST HALLWAY.
IN A SOUTHERN CELL.
IN AN EMPTY EAST CHAMBER.
IN A SMALL NORTH ROOM.
IN A FOUR-WAY INTERSECTION.
AT A BEND IN THE CORRIDOR (N AND W).
IN A FOUR-WAY INTERSECTION.
IN A WEST SIDE CHAMBER.
IN A NORTH-SOUTH HALLWAY.
AT A BEND IN THE CORRIDOR (W AND S).
IN A SMALL CHAMBER.
IN AN EAST-WEST HALLWAY.
AT A BEND IN THE HALLWAY (N AND W)
IN A FOUR-WAY INTERSECTION.
IN AN EAST SIDE CHAMBER.
IN A WEST SIDE CHAMBER.
AT THE END OF THE LINE.
Text found in Eamon_075_Temple_of_the_Guild_1991_Doumakes_D..do/EAMON.ROOMS.txt:
0
0
0
0
0
0
0
0
3
0
0
0
0
0
7
2
0
0
7
0
0
0
0
0
0
0
0
7
0
0
0
7
8
0
0
0
6
4
5
3
0
0
9
0
0
6
0
0
11
8
14
10
0
0
0
0
9
0
0
0
12
9
0
0
0
0
0
11
0
13
0
0
0
0
12
0
0
0
0
0
15
9
0
0
16
0
0
14
0
0
19
15
17
18
0
0
0
0
0
16
0
0
0
0
16
0
0
0
-99
16
0
0
0
0
Text found in Eamon_075_Temple_of_the_Guild_1991_Doumakes_D..do/GLADIATOR POOL.bas:
10 REM THE GLADIATOR POOL
20 DIM RN$(7),RB(7)
30 D$ = CHR$(4)
40 HOME
50 DATA COLOSSUS,GORGON II,GORGON I,MAYHEM 3,SARGON,MEDUSA,OTIS
60 DATA 10000,1000,700,400,300,200,75
70 FOR I = 1 TO 7: READ RN$(I): NEXT
80 FOR I = 1 TO 7: READ RB(I): NEXT
85 INVERSE
90 HTAB 13: PRINT "GLADIATOR POOL"
95 NORMAL
100 PRINT : PRINT
110 ONERR GOTO 150
120 PRINT D$"VERIFY BADGUY"
130 POKE 216,0
140 GOTO 1000
150 POKE 216,0: IF PEEK(222) < >6 THEN STOP
160 PRINT " A FEW OF THE WEALTHIER AND OLDER ADVENTURERS HAVE, WELL, SOMEWHAT GROTESQUE TASTE IN ENTERTAINMENT. THEY LIKE TO WATCH FIGHTS. NOT WRESTLING, WHICH IS DONE FOR SPORT AND EXERCISE,"
170 PRINT "BUT REAL FIGHTING WITH WEAPONS AND BLOOD. THEY HAVE INVENTED A SPECTATOR SPORT IN WHICH A ROBOT FIGHTER IS SET AGAINST A HUMAN ADVENTURER. THE HUMAN FIGHTERS ARE, APPROPRIATELY ENOUGH,"
180 PRINT "CALLED GLADIATORS. THE ROBOTS ARE QUITE DANGEROUS, ANDMANY GLADIATORS HAVE BEEN KILLED OR INJURED IN THE GAME. THERE IS NO CHANCETO FLEE FROM THE ARENA DURING COMBAT."
190 PRINT : PRINT "(HIT ANY KEY TO CONTINUE)";: GET R$: PRINT : HOME
200 PRINT " WHY, YOU MAY ASK, WOULD AN ADVENTURER DELIBERATELY RISK DEATH TO FIGHT A MACHINE? FOR MONEY, OF COURSE. THOSE ADVENTURERS WHO SURVIVE ARE PAID A HANDSOME BOUNTY, LARGE ENOUGH TO"
210 PRINT "ATTRACT A LARGE POOL OF FIGHTERS. THOSEWHO DON'T SURVIVE...WELL, THEY COULDN'T HAVE TAKEN IT WITH THEM ANYWAY."
220 PRINT : PRINT " IF YOU ARE IN NEED OF A SIZEABLE AMOUNT OF CASH, YOU MAY BE ABLE TO WIN IT WORKING IN THE GLADIATOR POOL."
230 PRINT : PRINT "(HIT ANY KEY TO CONTINUE)";: GET R$: PRINT : HOME
240 PRINT " AS YOU WALK INTO THE OFFICE OF GLADIATOR RECRUITMENT, YOU SEE THAT YOU CAN CHOOSE YOUR OPPONENT FROM THIS LIST:"
250 PRINT
260 PRINT TAB( 5);"NAME"; TAB( 28);"BOUNTY"
270 FOR I = 1 TO 7
280 PRINT
290 PRINT I;" ";RN$(I); TAB( 23);RB(I);" GOLD PIECES"
300 NEXT
310 PRINT
320 PRINT "ENTER NUMBER FOR YOUR CHOICE (1-7), OR ENTER '0' TO LEAVE.";
330 INPUT " ";C
340 IF C <0 OR C >7 OR C < > INT(C) THEN : HOME : GOTO 240
350 IF C = 0 THEN : PRINT D$"OPEN BADGUY": PRINT D$"DELETE BADGUY": PRINT D$"RUN LOBBY"
360 PRINT D$"OPEN BADGUY"
370 PRINT D$"WRITE BADGUY"
380 PRINT C
390 PRINT D$"CLOSE"
400 HOME
410 PRINT D$"RUN MAIN PROGRAM"
990 REM RETURN AFTER SUCCESSFUL FIGHT
1000 PRINT D$"OPEN BADGUY"
1010 PRINT D$"READ BADGUY"
1020 INPUT C
1030 PRINT D$"CLOSE"
1040 PRINT "YOU HAVE WON ";RB(C);" GOLD PIECES": PRINT "FOR THE DEFEAT OF ";RN$(C);"!"
1045 GOSUB 2000
1047 PRINT D$"DELETE BADGUY"
1050 PRINT : PRINT "CONGRATULATIONS!"
1060 GOLD = GOLD +RB(C)
1062 ERR = 0
1065 GOSUB 3000
1070 GOTO 230
1999 REM READ-CHARACTER SUBROUTINE
2000 PRINT D$"OPEN FRESH MEAT"
2010 PRINT D$"READ FRESH MEAT"
2020 INPUT REC
2030 INPUT NA$,HD,AG,CH
2040 FOR I = 1 TO 4: INPUT SA%(I): NEXT
2050 FOR I = 1 TO 5: INPUT WA%(I): NEXT
2060 INPUT AE,SEX$,GOLD,BANK,AC
2070 FOR I = 1 TO 4
2080 INPUT WN$(I)
2090 FOR J = 1 TO 4: INPUT WE%(I,J): NEXT
2100 NEXT
2110 PRINT D$"CLOSE"
2120 RETURN
2999 REM WRITE-CHARACTER SUBROUTINE
3000 REM
3050 PRINT D$"OPEN FRESH MEAT"
3060 PRINT D$"WRITE FRESH MEAT"
3070 PRINT REC
3080 PRINT NA$: PRINT HD: PRINT AG: PRINT CH
3090 FOR I = 1 TO 4: PRINT SA%(I): NEXT
3100 FOR I = 1 TO 5: PRINT WA%(I): NEXT
3110 PRINT AE: PRINT SEX$: PRINT GOLD: PRINT BANK: PRINT AC
3120 FOR I = 1 TO 4
3130 PRINT WN$(I)
3140 FOR J = 1 TO 4: PRINT WE%(I,J): NEXT
3150 NEXT
3160 PRINT D$"CLOSE"
3170 RETURN
Text found in Eamon_075_Temple_of_the_Guild_1991_Doumakes_D..do/LOBBY.bas:
1 REM LOBBY OF THE TEMPLE OF THE GUILD
10 D$ = CHR$(4)
15 DIM A$(39)
20 HOME
30 GOSUB 10000
140 PRINT "AS YOU ENTER THE LOBBY OF THE TEMPLE, YOU SEE A SIGN LABELED 'DIRECTORY.' IT SAYS:"
150 PRINT
160 PRINT "1. BUREAU OF NAMES"
170 PRINT "2. SHEEPSKINNER CASINO"
180 PRINT "3. GLADIATOR POOL"
190 PRINT "4. ADVENTURERS' PROVING GROUNDS"
200 PRINT
210 PRINT "ENTER YOUR CHOICE (1-4),"
220 PRINT "OR HIT '0' TO GO HOME."
225 VTAB 22: PRINT "(YOU ARE HOLDING ";GOLD;" GOLD PIECES.)"
230 GET R$: IF R$ <"0" OR R$ >"4" GOTO 230
235 PRINT
240 ON VAL(R$) GOTO 540,550,3000,2000
285 HOME : VTAB 10
290 PRINT "INSERT EAMON MASTER DISK AND HIT A KEY"
295 GET R$: PRINT
300 ONERR GOTO 510
305 PRINT D$"VERIFY EAMON.PIC"
306 POKE 216,0
380 GOSUB 11000
400 PRINT D$"OPEN THE ADVENTURER"
410 PRINT D$"WRITE THE ADVENTURER"
420 PRINT NA$
430 PRINT REC
440 PRINT D$"CLOSE"
450 POKE -16368,0
500 PRINT D$"RUN MAIN HALL"
510 POKE 216,0: IF PEEK(222) < >6 THEN STOP
515 GOTO 285
520 POKE 216,0: PRINT "ERROR TYPE "; PEEK(222);" IN LINE "; PEEK(218) + PEEK(219) *256
530 END
540 PRINT D$"RUN BUREAU OF NAMES"
550 PRINT : HOME : PRINT D$"RUN SHEEPSKINNER CASINO"
2000 HOME : PRINT D$"RUN PROVING GROUNDS"
3000 PRINT : HOME : PRINT D$"RUN GLADIATOR POOL"
9990 REM READ-CHARACTER SUBROUTINE
10000 PRINT D$"OPEN FRESH MEAT"
10010 PRINT D$"READ FRESH MEAT"
10020 INPUT REC
10030 INPUT NA$,HD,AG,CH
10040 FOR I = 1 TO 4: INPUT SA%(I): NEXT
10050 FOR I = 1 TO 5: INPUT WA%(I): NEXT
10060 INPUT AE,SEX$,GOLD,BANK,AC
10070 FOR I = 1 TO 4
10080 INPUT WN$(I)
10090 FOR J = 1 TO 4: INPUT WE%(I,J): NEXT
10100 NEXT
10110 PRINT D$"CLOSE"
10120 RETURN
10990 REM WRITE-CHARACTER SUBROUTINE
11000 PRINT D$"OPEN CHARACTERS,L150"
11090 PRINT D$"WRITE CHARACTERS,R";REC
11120 PRINT NA$: PRINT HD: PRINT AG: PRINT CH
11130 FOR I = 1 TO 4: PRINT SA%(I): NEXT
11140 FOR I = 1 TO 5: PRINT WA%(I): NEXT
11150 PRINT AE: PRINT SEX$: PRINT GOLD: PRINT BANK: PRINT AC
11160 FOR I = 1 TO 4
11170 PRINT WN$(I)
11180 FOR J = 1 TO 4: PRINT WE%(I,J): NEXT
11190 NEXT
11200 PRINT D$"CLOSE"
11210 RETURN
Text found in Eamon_075_Temple_of_the_Guild_1991_Doumakes_D..do/MAIN PROGRAM.bas:
1 REM EAMON ADVENTURE #75
2 REM ->TEMPLE OF THE GUILD<-
3 REM
4 REM BY DON DOUMAKES
5 REM
8 REM MEAMON ADVENTURER'S GUILD7625 HAWKHAVEN DR.CLEMMONS, NC 27012
10 ONERR GOTO 50
20 DK$ = CHR$(4): PRINT DK$"VERIFY GAME.PTRS": GOTO 19000
50 POKE 216,0: GOTO 1000
100 REM ///MAIN LOOP. FIRST GIVE ROOM DESC, THEN GET COMMAND
110 PRINT
120 IF SPD THEN SPD = SPD -1: IF NOT SPD THEN MD%(0,2) = MD%(0,2)/2:MD%(0,10) = MD%(0,10) -2 *MD%(0,2): IF RND(1) >.8 THEN PRINT "YOUR SPEED SPELL HAS JUST EXPIRED!": PRINT
130 IF V%(ROOM) THEN PRINT DK$;"READ EAMON.ROOM NAMES,R";ROOM: INPUT A$: PRINT DK$: PRINT "YOU ARE ": PRINT " ";A$: PRINT
140 IF NOT V%(ROOM) THEN PRINT DK$;"READ EAMON.DESC,R";ROOM: INPUT A$: PRINT DK$: PRINT A$: PRINT :V%(ROOM) = 1
150 FOR M = 1 TO NM: IF MD%(M,5) = ROOM AND MD%(M,15) THEN PRINT MN$(M);" IS HERE.": PRINT
160 IF MD%(M,5) = ROOM AND NOT MD%(M,15) THEN PRINT DK$;"READ EAMON.DESC,R";M +300: INPUT A$: PRINT DK$: PRINT A$:MD%(M,15) = 1: PRINT
170 NEXT M: FOR A = 1 TO NZ: IF AD%(A,4) = ROOM AND AD%(A,9) THEN PRINT "YOU SEE ";AN$(A)
180 IF AD%(A,4) = ROOM AND NOT AD%(A,9) THEN PRINT DK$;"READ EAMON.DESC,R";A +100: INPUT A$: PRINT DK$: PRINT A$:AD%(A,9) = 1: PRINT
190 NEXT A: FOR A = A TO NA: IF AD%(A,4) = ROOM THEN PRINT "YOUR ";AN$(A) +" IS HERE."
200 NEXT A:V%(ROOM) = 1
210 PRINT : INPUT " YOUR COMMAND?";A$
220 IF LEFT$(A$,1) = " " THEN A$ = MID$ (A$,2): GOTO 220
230 IF A$ = "" THEN A$ = CZ$: VTAB PEEK(37): HTAB 17: PRINT A$
235 IF A$ = "" THEN 275
240 CZ$ = A$: FOR A = 2 TO LEN(A$): IF MID$ (A$,A,1) < >" " THEN NEXT
250 V$ = LEFT$(A$,A -1):S$ = MID$ (A$,A +1)
260 IF LEFT$(S$,1) = " " THEN S$ = MID$ (S$,2): GOTO 260
270 FOR C = 1 TO 6: IF LEFT$(C$(C), LEN(V$)) = V$ THEN 290
272 NEXT :F = 0: FOR A = 7 TO NC: IF C$(A) = V$ THEN C = A: GOTO 290
273 IF LEFT$(C$(A), LEN(V$)) = V$ THEN F = F +1:C = A: IF F >1 THEN 275
274 NEXT : IF F THEN 290
275 PRINT : PRINT "HUH? I ONLY UNDERSTAND THESE COMMANDS-- ";: FOR C = 1 TO NC: PRINT C$(C); SPC( 20 - LEN(C$(C)));: NEXT : PRINT : PRINT : GOTO 210
280 IF C$(C) = S$ THEN S$ = V$:V$ = C$(C)
290 ON C GOTO 3000,3000,3000,3000,3000,3000,4000,4000,5000,6000,6000,7000,8000,9000,10000,11000,12000,13000,14000,15000,15000,16000,17000,18000
300 REM ///COMMANDS RETURN TO HERE
310 IF NOT NBTL THEN 500
320 FOR M = 1 TO NM: IF MD%(M,5) < >ROOM THEN 490
330 M2 = MD%(M,14) -(MD%(M,14) = 2):MR = FD%(M2)/TD%(M2) + INT(41 * RND(1) -20)
340 IF MD%(M,4) 1 THEN FOR A2 = 5 TO 8: INPUT AD%(A,A2): NEXT A2
1030 NEXT A: PRINT DK$;"OPEN EAMON.MONSTERS,L128": DIM MN$(NM),MD%(NM,15): FOR A = 1 TO NM: PRINT DK$;"READ EAMON.MONSTERS,R";A: INPUT MN$(A): FOR A2 = 1 TO 12: INPUT MD%(A,A2): NEXT A2,A: PRINT DK$;"CLOSE"
1031 ROOM = 1
1032 ONERR GOTO 1037
1033 PRINT DK$"VERIFY BADGUY": POKE 216,0
1035 PRINT DK$"OPEN BADGUY": PRINT DK$"READ BADGUY": INPUT GL: PRINT DK$"CLOSE":MD%(GL,5) = 1:ROOM = 0
1037 POKE 216,0: IF PEEK(222) < >6 THEN STOP
1039 ROOM = ROOM +1
1040 PRINT DK$;"OPEN FRESH MEAT": PRINT DK$;"READ FRESH MEAT": INPUT REC: INPUT MN$(0),MD%(0,1),MD%(0,2),CH: FOR A = 1 TO 4: INPUT SA%(A): NEXT : FOR A = 1 TO 5: INPUT WA%(A): NEXT : INPUT AE,SEX$,GOLD,BANK,AC
1050 NW = 15: DIM WN$(NW),WT%(NW),WO%(NW),WD%(NW),WP%(NW): FOR A = 1 TO 4: INPUT WN$(A),WT%(A),WO%(A),WD%(A),WS%(A): NEXT : PRINT DK$;"CLOSE"
1060 PRINT DK$;"OPEN EAMON.DESC,L256": PRINT DK$;"OPEN EAMON.ROOM NAMES,L64": PRINT DK$;"OPEN EAMON.ROOMS,L64"
1070 FOR W2 = 1 TO 4: IF WN$(W2) < >"NONE" THEN NA = NA +1:AN$(NA) = WN$(W2):AD%(NA,2) = 2:AD%(NA,3) = 2:AD%(NA,4) = -1:AD%(NA,5) = WO%(W2):AD%(NA,6) = WT%(W2):AD%(NA,7) = WD%(W2):AD%(NA,8) = WS%(W2): NEXT :W2 = 4
1080 WZ = W2:WT = W *WZ
1090 FOR W2 = 1 TO WZ: FOR A = 1 TO NA -WZ: IF AN$(A) = WN$(W2) THEN AN$(A) = AN$(A) +"#": FOR A = 0 TO 0: NEXT : GOTO 1090
1100 NEXT A,W2:EA = 0:MD%(0,8) = 0:A2 = INT(AC/2): IF A2 *2 < >AC THEN MD%(0,8) = 1:EA = -5
1110 IF A2 THEN MD%(0,8) = MD%(0,8) +A2:EA = EA -A2 *10: IF A2 = 3 THEN MD%(0,8) = MD%(0,8) +2:EA = EA -30
1120 IF NA >NZ THEN MD%(0,10) = (EA +AE) *( -EA >AE) +WO%(1) +WA%(WT%(1)) +2 *MD%(0,2):MD%(0,7) = 0:MD%(0,9) = NZ +1:MD%(0,11) = WD%(1):MD%(0,12) = WS%(1):MD%(0,14) = 3
1130 READ NC: DIM C$(NC): FOR C = 1 TO NC: READ C$(C): NEXT
1140 FOR S = 1 TO 4:S2%(S) = SA%(S): NEXT : DIM V%(96)
1200 REM SET UP THE "OTHER SELF" MONSTER
1210 FOR I = 1 TO 12:MD%(18,I) = MD%(0,I): NEXT
1213 MD%(18,3) = 0
1215 MD%(18,4) = 100
1217 MD%(18,5) = 19
1220 MD%(18,9) = 0
1900 GOTO 100
1910 DATA 24
1920 DATA NORTH,SOUTH,EAST,WEST,UP,DOWN,GET,TAKE,DROP,LOOK,EXAMINE,ATTACK,FLEE,GIVE,INVENTORY,BLAST,HEAL,POWER,SPEED,SMILE,WAVE,SAY,READY,SAVE
2000 REM ///DONE WITH GAME
2010 PRINT : PRINT "(HIT ANY KEY TO CONTINUE) ";: POKE -16368,0: GET A$: PRINT
2020 PRINT DK$"CLOSE": IF SPD THEN MD%(0,2) = MD%(0,2)/2
2030 IF DIE THEN 2500
2040 FOR W = 1 TO 4:WN$(W) = "NONE": NEXT :W2 = 1: FOR A = 1 TO NA: IF AD%(A,2) >1 AND AD%(A,4) = -1 THEN WN$(W2) = AN$(A):WP%(W2) = A:W2 = W2 +1:AD%(A,4) = 0
2050 NEXT A: IF W2 <6 THEN 2300
2060 HOME : PRINT "AS YOU START TO ENTER THE LOBBY, LORD WILLIAM MISSLEFIRE APPEARS AND TELLS YOU, 'YOU HAVE TOO MANY WEAPONS TO KEEP THEM ALL---FOUR IS THE LEGAL LIMIT.": PRINT : PRINT "YOUR WEAPONS ARE---"
2070 FOR W = 1 TO W2 -1: PRINT SPC( 4);W;"--";WN$(W): NEXT : PRINT : PRINT "ENTER THE NUMBER OF THE WEAPON TO THROW AWAY (1-";W2 -1;") "
2080 VTAB PEEK(37): HTAB 23: INPUT A$:W5 = VAL(A$): IF W5 <1 OR W5 >W2 -1 OR W5 < > INT(W5) THEN 2080
2090 AD%(WP%(W5),4) = -1:WN$(W5) = WN$(W2 -1):WP%(W5) = WP%(W2 -1):W2 = W2 -1: IF W2 >5 THEN 2060
2300 FOR W = 1 TO 4: IF WP%(W) THEN WT%(W) = AD%(WP%(W),6):WO%(W) = AD%(WP%(W),5):WD%(W) = AD%(WP%(W),7):WS%(W) = AD%(WP%(W),8)
2310 NEXT W
2400 IF NOT GL THEN PRINT DK$"OPEN PRIZE": PRINT DK$"READ PRIZE": FOR I = 1 TO 3: INPUT P9(I): NEXT : PRINT DK$"CLOSE":MD%(0,1) = MD%(0,1) +P9(1):MD%(0,2) = MD%(0,2) +P9(2):CH = CH +P9(3)
2410 PRINT DK$"OPEN FRESH MEAT": PRINT DK$"WRITE FRESH MEAT"
2420 PRINT REC: PRINT MN$(0): PRINT MD%(0,1): PRINT MD%(0,2): PRINT CH: FOR A = 1 TO 4: PRINT SA%(A): NEXT : FOR A = 1 TO 5: PRINT WA%(A): NEXT : PRINT AE: PRINT SEX$: PRINT GOLD: PRINT BANK: PRINT AC
2430 FOR A = 1 TO 4: PRINT WN$(A): PRINT WT%(A): PRINT WO%(A): PRINT WD%(A): PRINT WS%(A): NEXT
2440 PRINT DK$"CLOSE"
2445 IF GL THEN PRINT DK$"RUN GLADIATOR POOL"
2460 PRINT DK$"RUN LOBBY"
2500 ONERR GOTO 2500
2510 HOME : VTAB 5: PRINT "(INSERT EAMON MASTER DISKETTE, THEN": PRINT " HIT THE 'C' KEY) ";: POKE -16368,0
2520 GET A$: IF A$ < >"C" THEN 2520
2530 PRINT A$
2540 IF DIE THEN PRINT DK$;"OPEN THE ADVENTURER,S6,D1": PRINT DK$;"DELETE THE ADVENTURER": GOTO 2900
2550 PRINT DK$;"OPEN CHARACTERS,L150,S6,D1": PRINT DK$;"WRITE CHARACTERS,R";REC: PRINT MN$(0): PRINT MD%(0,1): PRINT MD%(0,2): PRINT CH: FOR A = 1 TO 4: PRINT SA%(A): NEXT
2560 FOR A = 1 TO 5: PRINT WA%(A): NEXT : PRINT AE: PRINT SEX$: PRINT GOLD: PRINT BANK: PRINT AC: FOR A = 1 TO 4: PRINT WN$(A): PRINT WT%(A): PRINT WO%(A): PRINT WD%(A): PRINT WS%(A): NEXT
2570 PRINT DK$;"OPEN THE ADVENTURER": PRINT DK$;"WRITE THE ADVENTURER": PRINT MN$(0): PRINT REC: PRINT DK$;"CLOSE"
2900 PRINT DK$;"RUN MAIN HALL,S6,D1"
3000 REM ///MOVE COMMAND
3010 IF NBTL AND S$ < >"FLEE" THEN PRINT : PRINT "YOU CAN'T DO THAT WITH UNFRIENDLIES ABOUT!": PRINT : GOTO 100
3020 FOR D = 1 TO 6: IF LEFT$(V$,1) < > MID$ ("NSEWUD",D,1) THEN NEXT
3030 PRINT DK$;"READ EAMON.ROOMS,R";ROOM: FOR D2 = 1 TO D: INPUT R2: NEXT : PRINT DK$
3040 IF R2 >0 THEN 3500
3050 REM ///SPECIAL MOVES
3060 IF R2 = -99 THEN PRINT : PRINT "YOU SUCCESSFULLY RIDE OFF INTO THE": PRINT " SUNSET.": GOTO 2000
3070 IF NOT R2 THEN 3490
3490 PRINT : PRINT "YOU CAN'T GO THAT WAY!":V%(ROOM) = 0: GOTO 100
3500 R3 = ROOM:ROOM = R2: GOSUB 3600
3590 GOTO 100
3600 REM ///CHECK REACTIONS ON MONSTERS
3610 TD%(1) = 0:TD%(3) = MD%(0,1):FD%(1) = 0:FD%(3) = MD%(0,13)
3620 FOR M = 1 TO NM: IF MD%(M,5) = R3 THEN IF MD%(M,14) = 3 OR (MD%(M,14) = 1 AND 200 * RND(1) ROOM THEN 3900
3640 IF MD%(M,14) THEN 3670
3650 FR = MD%(M,3): IF FR AND FR < >100 THEN FR = FR + INT((CH -10)/2)
3660 MD%(M,14) = 1: IF FR >(100 * RND(1)) THEN MD%(M,14) = 2: IF FR >(100 * RND(1)) THEN MD%(M,14) = 3
3670 A = MD%(M,14):FD%(A) = FD%(A) +MD%(M,13):TD%(A) = TD%(A) +MD%(M,1)
3900 NEXT M:NBTL = (TD%(1) >0): RETURN
4000 REM ///GET COMMAND
4010 GOSUB 4900
4020 IF S$ = "ALL" THEN 4160
4120 FOR A = 1 TO NA: IF (AN$(A) < >S$ AND LEFT$(AN$(A), LEN(S$)) < >S$ AND RIGHT$(AN$(A), LEN(S$)) < >S$) OR AD%(A,4) < >ROOM THEN NEXT : PRINT : PRINT "I SEE NO ";S$;" HERE!": PRINT : GOTO 100
4130 GOSUB 4200: IF WT +AD%(A,3) >10 *MD%(0,1) THEN PRINT : PRINT "IT IS TOO HEAVY FOR YOU.": PRINT : GOTO 100
4140 PRINT : PRINT "GOT IT.":AD%(A,4) = -1:WT = WT +AD%(A,3): PRINT : IF AD%(A,2) <2 OR MD%(0,9) < > -1 THEN 300
4150 GOTO 17000
4160 FOR A = 1 TO NA: IF AD%(A,4) < >ROOM THEN 4190
4170 GOSUB 4200: IF WT +AD%(A,3) >10 *MD%(0,1) THEN PRINT AN$(A);" IS TOO HEAVY": GOTO 4190
4180 PRINT AN$(A) +" TAKEN.":AD%(A,4) = -1:WT = WT +AD%(A,3)
4190 NEXT : PRINT : GOTO 300
4200 REM ///INSERT HERE SPECIAL EFFECTS OF PICKING SOMETHING UP
4210 RETURN
4900 REM ///ROUTINE TO GET S$ IF NOT PREVIOUSLY SPECIFIED.
4905 IF S$ = "" THEN PRINT : PRINT C$(C);" WHAT";: INPUT S$: GOTO 4900
4910 RETURN
5000 REM ///DROP COMMAND
5010 GOSUB 4900
5020 IF S$ = "ALL" THEN 5100
5030 FOR A = 1 TO NA: IF (AN$(A) < >S$ AND LEFT$(AN$(A), LEN(S$)) < >S$ AND RIGHT$(AN$(A), LEN(S$)) < >S$) OR AD%(A,4) < > -1 THEN NEXT : PRINT : PRINT "YOU AREN'T CARRYING A ";S$: PRINT : GOTO 100
5040 WT = WT -AD%(A,3):AD%(A,4) = ROOM: PRINT AN$(A);" DROPPED.": PRINT
5050 IF WT >10 *MD%(0,1) THEN PRINT "YOU SUDDENLY FIND YOU CANNOT CARRY ALL OF THE ITEMS YOU ARE CARRYING, AND THEY ALL FALL TO THE GROUND.": PRINT : GOTO 5100
5060 IF MD%(0,9) >0 THEN IF AD%(MD%(0,9),4) < > -1 THEN MD%(0,9) = -1
5070 GOTO 300
5100 FOR A = 1 TO NA: IF AD%(A,4) = -1 THEN PRINT AN$(A);" DROPPED.":AD%(A,4) = ROOM
5110 NEXT A:WT = 0: GOTO 5060
6000 REM ///LOOK COMMAND
6020 LK = 0: FOR A = 1 TO NZ: IF AN$(A) = S$ AND (AD%(A,4) = ROOM OR AD%(A,4) = -1) THEN PRINT DK$;"READ EAMON.DESC,R";A +100: INPUT A$: PRINT DK$: PRINT : PRINT A$: PRINT :LK = 1
6030 NEXT A: IF LK THEN 300
6040 FOR A = 1 TO NM: IF MN$(A) = S$ AND MD%(A,5) = ROOM THEN PRINT DK$;"READ EAMON.DESC,R";A +300: INPUT A$: PRINT DK$: PRINT : PRINT A$: PRINT :LK = 1
6050 NEXT A: IF LK THEN 300
6055 IF ROOM = 6 THEN PRINT : PRINT "YOU FOUND A SECRET DOOR IN THE EAST WALL!": PRINT
6060 V%(ROOM) = 0: GOTO 300
7000 REM ///ATTACK COMMAND
7010 GOSUB 4900
7280 FOR M = 1 TO NM: IF (S$ < >MN$(M) AND LEFT$(MN$(M), LEN(S$)) < >S$ AND RIGHT$(MN$(M), LEN(S$)) < >S$) OR MD%(M,5) < >ROOM THEN NEXT : PRINT : PRINT "ATTACK WHO?": PRINT : GOTO 100
7290 IF MD%(0,9) = -1 THEN PRINT : PRINT "YOU HAVE NO WEAPON READY!": PRINT : GOTO 100
7300 OF = 0:DF = M: GOSUB 7500: IF NOT HIT THEN 7360
7310 IF INC THEN W2 = AD%(MD%(0,9),6):WA%(W2) = WA%(W2) +2
7320 IF -EA < = AE THEN 300
7330 IF INT(100 * RND(1) +1) < = MD%(0,10) THEN 7360
7340 A = 2: IF EA +AE = -1 THEN A = 1
7350 AE = AE +A:MD%(0,10) = MD%(0,10) +A
7360 IF MD%(DF,14) = 1 OR DF = 0 THEN 300
7370 MD%(DF,3) = MD%(DF,3)/2: FOR M = 1 TO NM: IF MD%(M,5) = ROOM AND MD%(M,14) >1 THEN MD%(M,14) = 0
7380 NEXT M:R3 = ROOM: GOSUB 3600: GOTO 300
7400 REM ///MONSTER TRIES TO PICK UP WEAPON
7410 IF MD%(OF,10) = 0 THEN RETURN
7420 FOR A = 1 TO NA: IF AD%(A,4) < >ROOM OR AD%(A,2) <2 THEN NEXT : RETURN
7430 PRINT MN$(OF);" PICKS UP ";AN$(A): PRINT :AD%(A,4) = 0:MD%(OF,9) = A:MD%(OF,10) = MD%(OF,10) +AD%(A,5):MD%(OF,4) = MD%(OF,4) *2: RETURN
7500 HIT = 0: IF MD%(OF,9) = -1 THEN 7400
7505 PRINT MN$(OF);" ATTACKS ";MN$(DF): PRINT " --";:RL = INT(100 * RND(1) +1):HIT = 0: IF (RL <5 OR RL 95 THEN 7550
7540 PRINT " WEAPON BROKEN!":AD%(MD%(OF,9),4) = 0:MD%(OF,10) = MD%(OF,10) -AD%(MD%(OF,9),5):MD%(OF,9) = -1:MD%(OF,4) = MD%(OF,4)/2: IF RND(1) >.5 THEN PRINT : RETURN
7545 PRINT " BROKEN WEAPON HURTS USER!"
7550 IF FR = 100 THEN 7560
7555 D = MD%(OF,11):S = MD%(OF,12):DF = OF:A = 1: GOTO 7635
7560 D = MD%(OF,11) *2:S = MD%(OF,12):DF = OF:A = 0: GOTO 7635
7600 INC = ( INT(100 * RND(1) +1) >MD%(OF,10)):MD%(OF,10) = MD%(OF,10) +2 *INC
7605 D = MD%(OF,11):S = MD%(OF,12):A = 1: IF RL >5 THEN PRINT "A HIT!": GOTO 7635
7610 PRINT "A CRITICAL HIT!":R2 = INT(100 * RND(1) +1): IF R2 <51 THEN A = 0: GOTO 7635
7615 IF R2 <86 THEN S = 1.5 *S: GOTO 7635
7620 IF R2 <96 THEN D = 2 *D: GOTO 7635
7625 IF R2 <100 THEN D = 3 *D: GOTO 7635
7630 GOTO 7700
7635 D2 = 0: FOR D3 = 1 TO D:D2 = D2 + INT(S * RND(1) +1): NEXT :D2 = D2 -A *MD%(DF,8): IF D2 <1 THEN PRINT " BLOW BOUNCES OFF ARMOUR": PRINT : RETURN
7640 MD%(DF,13) = MD%(DF,13) +D2: IF MD%(DF,13) > = MD%(DF,1) THEN 7700
7645 A = MD%(DF,14):FD%(A) = FD%(A) +D2
7650 PRINT : PRINT MN$(DF);: ON INT(MD%(DF,13) *5/MD%(DF,1) +1) GOTO 7655,7660,7665,7670,7675
7655 PRINT " IS STILL IN GOOD": PRINT " SHAPE.": RETURN
7660 PRINT " IS HURTING.": RETURN
7665 PRINT " IS IN PAIN.": RETURN
7670 PRINT " IS VERY BADLY INJURED.": RETURN
7675 PRINT " IS AT DEATH'S DOOR,": PRINT " KNOCKING LOUDLY.": RETURN
7700 PRINT MN$(DF);" IS DEAD!": PRINT :A = MD%(DF,14):FD%(A) = FD%(A) +MD%(DF,1) -MD%(DF,13) +D2:MD%(DF,5) = 0
7710 A2 = DF:AD%(A2,4) = ROOM: FOR AJ = 1 TO NA: IF AD%(AJ,4) = -DF -1 THEN AD%(AJ,4) = ROOM
7720 NEXT : IF MD%(DF,9) >0 THEN AD%(MD%(DF,9),4) = ROOM:MD%(DF,10) = MD%(DF,10) -AD%(MD%(DF,9),5):MD%(DF,9) = -1:MD%(DF,4) = MD%(DF,4)/2
7740 IF DF = 0 THEN DIE = 1: GOTO 2000
7900 PRINT : RETURN
8000 REM ///FLEE COMMAND
8010 IF NOT NBTL THEN PRINT : PRINT "THERE'S NOTHING TO FLEE FROM!": PRINT : GOTO 100
8020 FOR D = 1 TO 6: IF S$ = C$(D) THEN V$ = S$:S$ = "FLEE": GOTO 3000
8030 NEXT
8490 DR$ = "": GOSUB 8500: IF DR$ = "000000" THEN PRINT : PRINT "THERE'S NO PLACE TO GO!!": GOTO 100
8495 GOTO 3500
8500 PRINT DK$;"READ EAMON.ROOMS,R";ROOM: FOR D = 1 TO 6: INPUT DR%(D):DR$ = DR$ + STR$(DR%(D)): NEXT : PRINT DK$
8510 R2 = DR%(6 * RND(1) +1): IF R2 <1 THEN 8510
8515 IF ROOM = 19 AND R2 = -99 GOTO 8510
8520 RETURN
9000 REM ///GIVE COMMAND
9010 A2 = 1
9020 FOR M = 1 TO NM: IF LEFT$(S$, LEN(MN$(M))) = MN$(M) AND MD%(M,5) = ROOM THEN 9050
9030 NEXT : IF A2 = 1 THEN A2 = 2: PRINT : INPUT "WHO TO GIVE TO? ";S$: GOTO 9020
9040 PRINT : PRINT "NOBODY HERE BY THAT NAME!": PRINT : GOTO 100
9050 S$ = MID$ (S$, LEN(MN$(M)) +1)
9060 IF LEFT$(S$,1) = " " THEN S$ = MID$ (S$,2): GOTO 9060
9065 IF VAL(S$) >0 THEN 9500
9070 FOR A = 1 TO NA: IF LEFT$(S$, LEN(AN$(A))) = AN$(A) AND AD%(A,4) = -1 THEN 9095
9080 NEXT : IF A2 = 2 THEN A2 = 3: PRINT : INPUT "WHAT TO GIVE? ";S$: GOTO 9065
9090 PRINT : PRINT "YOU AREN'T CARRYING A ";S$;"!": PRINT : GOTO 100
9095 IF A = MD%(0,9) THEN MD%(0,9) = -1
9100 PRINT : PRINT "OKAY.":AD%(A,4) = -M -1:MD%(M,14) = 0:MD%(M,3) = MD%(M,3) *(1 +AD%(A,1)/100)
9110 IF MD%(M,10) < >0 AND MD%(M,9) = -1 THEN MD%(M,9) = A:MD%(M,10) = MD%(M,9) +AD%(A,5):MD%(M,4) = 2 *MD%(M,4)
9120 R3 = ROOM: GOSUB 3600: GOTO 5050
9500 IF VAL(S$) >GOLD THEN PRINT : PRINT "YOU AREN'T CARRYING THAT MUCH GOLD OF YOUR OWN!": PRINT : GOTO 300
9510 GOLD = INT(GOLD - VAL(S$)):MD%(M,14) = 0:MD%(M,3) = MD%(M,3) *(1 + VAL(S$)/100): GOTO 9120
10000 REM ///INVENTORY COMMAND
10010 PRINT : PRINT "YOU ARE CARRYING THE FOLLOWING--":A0 = 0: FOR A = 1 TO NA: IF AD%(A,4) = -1 THEN PRINT " ";AN$(A); LEFT$(" (READY WEAPON)",1 +20 *(A = MD%(0,9))):A0 = A0 +1: IF A0 = 15 THEN PRINT : PRINT "(HIT ANY KEY TO CONTINUE)";: GET A$: PRINT :A0 = 0
10020 NEXT : GOTO 300
11000 REM ///BLAST SPELL
11010 GOSUB 4900
11470 FOR M = 1 TO NM: IF S$ < >MN$(M) OR MD%(M,5) < >ROOM THEN NEXT : PRINT : PRINT "YOU CAN'T BLAST ";S$;"!": PRINT : GOTO 100
11480 S = 1: GOSUB 11500: IF NOT SUC THEN 300
11490 PRINT : PRINT "DIRECT HIT!": PRINT :S = 6:D = 1:DF = M:A = 0: GOSUB 7635: PRINT : GOTO 300
11500 SUC = 0: IF SA%(S) THEN RL = INT(100 * RND(1) +1):SUC = (((RL S2%(S) THEN S2%(S) = S2%(S) +2:SA%(S) = SA%(S) +2
11530 S2%(S) = S2%(S)/2
11540 RETURN
11600 PRINT : PRINT "THE STRAIN OF ATTEMPTING TO CAST THIS SPELL OVERLOADS YOUR BRAIN AND YOU FORGET IT COMPLETELY.": PRINT :SA%(S) = 0: RETURN
12000 REM ///HEAL SPELL
12010 S = 2: GOSUB 11500: IF NOT SUC THEN 300
12020 PRINT : IF MD%(0,13) THEN PRINT "SOME OF YOUR WOUNDS SEEM TO CLEAR UP.": PRINT
12030 MD%(0,13) = MD%(0,13) - INT(10 * RND(1) +1): IF MD%(0,13) <0 THEN MD%(0,13) = 0
12040 DF = 0: GOSUB 7650: GOTO 300
13000 REM ///POWER SPELL--RE-WRITE THIS SECTION FOR YOUR OWN SPECIAL PLOTS
13010 S = 4: GOSUB 11500: IF NOT SUC THEN 300
13020 RAISE = 0: FOR M = 1 TO NM:M2 = NZ -NM +M: IF AD%(M2,4) = ROOM OR AD%(M2,4) = -1 THEN RAISE = 1: PRINT MN$(M);" COMES ALIVE!":AD%(M2,4) = 0:MD%(M,5) = ROOM:MD%(M,13) = 0:WT = WT -AD%(M2,3)
13030 NEXT M: IF RAISE THEN R3 = ROOM: GOSUB 3600: GOTO 300
13040 FOR A = 1 TO NA: IF AD%(A,4) = ROOM THEN RAISE = 1: PRINT AN$(A);" VANISHES!":AD%(A,4) = 0
13050 NEXT A: IF RAISE THEN PRINT : GOTO 300
13060 RR = INT(100 * RND(1) +1): IF RR <11 THEN PRINT : PRINT "THE SECTION OF TUNNEL YOU ARE IN ": PRINT " COLLAPSES AND YOU DIE.":DIE = 1: GOTO 2000
13080 IF RR <86 THEN PRINT : PRINT "YOU HEAR A VERY LOUD SONIC BOOM": PRINT " THAT ECHOES THROUGH THE TUNNELS.": PRINT : GOTO 300
13090 IF RR >95 THEN PRINT : PRINT "ALL OF YOUR HITS ARE HEALED.": PRINT :MD%(0,13) = 0: GOTO 300
13100 GOTO 14020
14000 REM ///SPEED SPELL
14010 S = 3: GOSUB 11500: IF NOT SUC THEN 300
14020 IF NOT SPD THEN MD%(0,10) = MD%(0,10) +2 *MD%(0,2):MD%(0,2) = 2 *MD%(0,2)
14030 SPD = SPD + INT(25 * RND(1) +10): PRINT : PRINT "YOU CAN FEEL THE NEW AGILITY FLOWING": PRINT " THROUGH YOU!": PRINT : GOTO 300
15000 REM ///SMILE COMMAND
15010 PRINT : FOR M = 1 TO NM: IF MD%(M,5) < >ROOM THEN 15100
15020 ON MD%(M,14) GOTO 15030,15040,15050
15030 PRINT MN$(M);" GROWLS AT YOU": GOTO 15100
15040 PRINT MN$(M);" IGNORES YOU": GOTO 15100
15050 PRINT MN$(M);" ";V$;"S BACK": GOTO 15100
15100 NEXT M: PRINT : GOTO 300
16000 REM ///SAY COMMAND
16010 GOSUB 4900
16030 IF S$ = "BLAST" THEN V$ = S$:S$ = "": GOTO 11000
16040 IF S$ = "HEAL" THEN 12000
16050 IF S$ = "POWER" THEN 13000
16060 IF S$ = "SPEED" THEN 14000
16900 PRINT : PRINT "OKAY, '";S$;"'": PRINT : GOTO 300
17000 REM ///READY A WEAPON.
17010 GOSUB 4900
17020 FOR A = 1 TO NA: IF AN$(A) < >S$ OR AD%(A,4) < > -1 THEN NEXT : PRINT : PRINT "YOU AREN'T CARRYING IT!": PRINT : GOTO 100
17030 IF AD%(A,2) <2 THEN PRINT : PRINT "THAT ISN'T A WEAPON!": PRINT : GOTO 100
17980 MD%(0,10) = (EA +AE) *( -EA >AE) +AD%(A,5) +WA%(AD%(A,6)) +2 *MD%(0,2):MD%(0,9) = A:MD%(0,11) = AD%(A,7):MD%(0,12) = AD%(A,8)
17990 PRINT : PRINT "READIED.": PRINT : GOTO 300
18000 REM // SAVE GAME
18010 PRINT : PRINT "DO YOU WANT TO SAVE THIS GAME? ": PRINT "(Y/N) :";
18020 GET A$: IF A$ < >"Y" AND A$ < >"N" THEN 18020
18030 PRINT A$: IF A$ = "N" THEN 100
18040 PRINT DK$;"CLOSE":X = FRE(0)
18050 PRINT DK$"BSAVE GAME.PTRS,A$69,L8"
18060 PRINT DK$"BSAVE GAME.SVAR,A"; PEEK(105) + PEEK(106) *256;",L"; PEEK(109) + PEEK(110) *256 - PEEK(105) - PEEK(106) *256 +1
18070 PRINT DK$"BSAVE GAME.STR,A"; PEEK(111) + PEEK(112) *256;",L"; PEEK(115) + PEEK(116) *256 - PEEK(111) - PEEK(112) *256 +1
18080 PRINT : PRINT "THE GAME IS NOW SAVED. BOOT ON THIS": PRINT " DISKETTE TO RESTART THE GAME."
18090 END
19000 REM /// RESTART
19010 PRINT : PRINT "DO YOU WANT TO RESTART THIS GAME?": PRINT " Y OR N:";
19020 GET A$: IF A$ < >"Y" AND A$ < >"N" THEN 19020
19030 PRINT A$: IF A$ = "N" THEN END
19040 PRINT DK$"BLOAD GAME.PTRS": PRINT DK$"BLOAD GAME.SVAR": PRINT DK$"BLOAD GAME.STR"
19050 PRINT DK$;"DELETE GAME.PTRS": PRINT DK$;"DELETE GAME.SVAR": PRINT DK$;"DELETE GAME.STR"
19060 PRINT DK$;"OPEN EAMON.DESC,L256": PRINT DK$;"OPEN EAMON.ROOMS,L64": PRINT DK$;"OPEN EAMON.ROOM NAMES,L64"
19070 GOTO 100
Text found in Eamon_075_Temple_of_the_Guild_1991_Doumakes_D..do/PRIZE.txt:
0
1
0
Text found in Eamon_075_Temple_of_the_Guild_1991_Doumakes_D..do/PROVING GROUNDS.bas:
10 REM PROVING GROUNDS
15 D$ = CHR$(4)
20 HOME
30 T$ = "ADVENTURERS' PROVING GROUNDS"
40 INVERSE
50 HTAB 20 - LEN(T$)/2: PRINT T$
60 NORMAL
70 PRINT : PRINT
80 PRINT " YOU HAVE COME TO THE INNERMOST AND MOST EXCLUSIVE OF THE ROOMS IN THE TEMPLE OF THE GUILD. THIS IS THE PLACE WHERE ADVENTURERS COME FOR CHANGES IN THE BASIC STUFF OF THEMSELVES. IF YOU"
90 PRINT "HAVE A DESIRE TO BE A BETTER ADVENTURER,A DESIRE SO STRONG THAT YOU ARE WILLING TO SPEND YOUR FORTUNE AND RISK YOUR LIFEAS WELL, THIS MAY BE THE PLACE WHERE YOUREACH THAT GOAL."
100 PRINT
110 PRINT " TO INCREASE ANY OF YOUR BASIC CHARACTERISTICS (HARDINESS, AGILITY, OR CHARISMA), YOU MUST PAY A FEE AND MEET ATEST. THOSE WHO CANNOT MEET THE TEST LOSE THEIR LIVES."
120 PRINT
125 GOSUB 2000
130 PRINT "(PRESS ANY KEY TO CONTINUE...)";: GET R$: PRINT : HOME
140 PRINT " TO RAISE YOUR CHARISMA ONE POINT WILL COST YOU A MERE 5,000 GOLD PIECES. A ONE-POINT INCREASE IN EITHER HARDINESSOR AGILITY WILL COST YOU 10,000 GOLD PIECES."
160 PRINT
170 IF GOLD > = 5000 GOTO 200
180 PRINT " SINCE YOU DON'T HAVE ENOUGH GOLD ONYOU, YOU OF COURSE WON'T HAVE THE CHANCETO PROVE YOURSELF HERE. BE GONE."
190 PRINT : PRINT "(PRESS ANY KEY TO CONTINUE...)": GET R$: PRINT : PRINT D$"RUN LOBBY"
200 PRINT " WOULD YOU BE INTERESTED IN RAISING YOUR HARDINESS, YOUR AGILITY, OR YOUR CHARISMA?"
205 PRINT : PRINT " OR WOULD YOU PREFER TO LEAVE?"
210 PRINT : PRINT : PRINT
220 PRINT "(PRESS H, A, C, OR L)";
230 GET R$: IF R$ < >"H" AND R$ < >"A" AND R$ < >"C" AND R$ < >"L" GOTO 230
235 PRINT
240 IF R$ = "L" THEN : PRINT : PRINT "WELL, GOOD DAY THEN.": PRINT D$"RUN LOBBY"
250 IF R$ = "H" THEN P = 1: GOTO 280
260 IF R$ = "A" THEN P = 2: GOTO 280
270 P = 3
280 P$(1) = "HARDINESS":P$(2) = "AGILITY":P$(3) = "CHARISMA"
290 IF P <3 AND GOLD <10000 THEN : PRINT "YOU DON'T HAVE ENOUGH GOLD TO GO CHANGING YOUR ";P$(P);"!": PRINT : GOTO 200
295 PRINT
300 PRINT "ARE YOU QUITE SURE YOU WANT TO CHANGE YOUR ";P$(P);"?": PRINT : PRINT "(PRESS Y OR N) ";
305 GET R$: IF R$ < >"Y" AND R$ < >"N" GOTO 305
307 PRINT
310 IF R$ = "N" GOTO 200
320 PRINT : PRINT "VERY WELL THEN..."
330 P%(P) = 1
340 PRINT D$"OPEN PRIZE": PRINT D$"WRITE PRIZE"
350 FOR I = 1 TO 3: PRINT P%(I): NEXT
360 PRINT D$"CLOSE"
365 GOLD = GOLD -5000: IF P <3 THEN GOLD = GOLD -5000
367 GOSUB 3000
370 PRINT D$"RUN MAIN PROGRAM"
1999 REM READ-CHARACTER SUBROUTINE
2000 PRINT D$"OPEN FRESH MEAT"
2010 PRINT D$"READ FRESH MEAT"
2020 INPUT REC
2030 INPUT NA$,HD,AG,CH
2040 FOR I = 1 TO 4: INPUT SA%(I): NEXT
2050 FOR I = 1 TO 5: INPUT WA%(I): NEXT
2060 INPUT AE,SEX$,GOLD,BANK,AC
2070 FOR I = 1 TO 4
2080 INPUT WN$(I)
2090 FOR J = 1 TO 4: INPUT WE%(I,J): NEXT
2100 NEXT
2110 PRINT D$"CLOSE"
2120 RETURN
2999 REM WRITE-CHARACTER SUBROUTINE
3000 PRINT D$"OPEN FRESH MEAT"
3060 PRINT D$"WRITE FRESH MEAT"
3070 PRINT REC
3080 PRINT NA$: PRINT HD: PRINT AG: PRINT CH
3090 FOR I = 1 TO 4: PRINT SA%(I): NEXT
3100 FOR I = 1 TO 5: PRINT WA%(I): NEXT
3110 PRINT AE: PRINT SEX$: PRINT GOLD: PRINT BANK: PRINT AC
3120 FOR I = 1 TO 4
3130 PRINT WN$(I)
3140 FOR J = 1 TO 4: PRINT WE%(I,J): NEXT
3150 NEXT
3160 PRINT D$"CLOSE"
3170 RETURN
Text found in Eamon_075_Temple_of_the_Guild_1991_Doumakes_D..do/SHEEPSKINNER CASINO.bas:
10 D$ = CHR$(4)
12 DIM X(16),Y(16),FM$(39)
15 PRINT D$"OPEN FRESH MEAT": PRINT D$"READ FRESH MEAT": FOR I = 1 TO 39: INPUT FM$(I): NEXT : PRINT D$"CLOSE"
20 GOLD = VAL(FM$(17))
30 DATA 20,1,25,2,30,4,33,7,35,11,33,15,30,18,25,20,20,21,15,20,10,18,7,15,5,11,7,7,10,4,15,2
40 FOR I = 1 TO 16
50 READ X(I),Y(I)
60 NEXT
61 DIM PRIME(20),WR$(6),WR(6),ODDS(6,2),SC(7),B(6,2)
62 FOR I = 1 TO 20: READ PRIME(I): NEXT
63 DATA 2,3,5,7,11,13,17,19,23,29,31,37,41,43,47,53,59,61,67,71
64 FOR I = 1 TO 6: READ WR$(I),WR(I): NEXT
65 DATA SPARTUS,.6
66 DATA CYRO,.5
67 DATA CONAN,.7
68 DATA CLAUDIUS,.4
69 DATA ATHENIUS,.6
70 DATA ZELANO,.7
100 HOME
105 VTAB 20: PRINT "YOU HAVE ";GOLD;" GOLD PIECES.": VTAB 1
110 INVERSE : HTAB 11: PRINT "SHEEPSKINNER CASINO": NORMAL
120 PRINT : PRINT "AS YOU ENTER THE CASINO, YOU SEE THAT YOU CAN:"
130 PRINT
140 PRINT "1. PLAY AT THE WHEEL OF FORTUNE."
150 PRINT "2. BET ON THE FIGHTS."
170 PRINT "3. LEAVE."
180 PRINT : PRINT "HIT A KEY FOR YOUR CHOICE (1-3) ";
190 GET R$: IF R$ <"1" OR R$ >"3" GOTO 190
200 ON VAL(R$) GOTO 500,710,5000
500 HOME : INVERSE : PRINT "WHEEL OF": PRINT "FORTUNE": NORMAL
505 FOR I = 1 TO 16: HTAB X(I): VTAB Y(I): PRINT I: NEXT
510 VTAB 23: CALL -958
515 INPUT "HOW MUCH GOLD WILL YOU BET? ";BET
520 IF BET = 0 GOTO 100
525 IF BET >GOLD OR BET < > INT(BET) GOTO 510
530 VTAB 23: CALL -958
535 INPUT "BETTING ON WHICH NUMBER (1-16)? ";NUM
540 IF NUM <1 OR NUM >16 OR NUM < > INT(NUM) GOTO 530
545 REM SELECT FINAL NUMBER
550 F = 40 - INT( RND(1) *16 +1)
555 REM SPIN WHEEL
560 K = 1
565 FOR I = 1 TO F
570 INVERSE : HTAB X(K): VTAB Y(K): PRINT K: NORMAL
575 Z1 = -16336:Z2 = PEEK(Z1):Z2 = PEEK(Z1)
580 FOR J = 1 TO I *25 *I/F: NEXT
585 IF I = F GOTO 600
590 HTAB X(K): VTAB Y(K): PRINT K
595 K = K +1: IF K = 17 THEN K = 1
600 NEXT
605 REM WIN OR LOSE?
610 IF K = NUM THEN : VTAB 23: CALL -958: PRINT "YOU WIN ";BET *15;" GOLD PIECES!":GOLD = GOLD +BET *15: GOTO 620
615 VTAB 23: CALL -958: PRINT "YOU LOSE!":GOLD = GOLD -BET
620 PRINT "(HIT ANY KEY TO CONTINUE)";: GET R$: VTAB 23: PRINT : GOTO 505
697 REM BETTING ON THE FIGHTS
700 REM ASSIGN FIGHTERS RANDOMLY TO EACH OTHER.
710 FOR I = 1 TO 5: FOR J = I +1 TO 6
720 IF RND(1) >.5 THEN :H$ = WR$(I):WR$(I) = WR$(J):WR$(J) = H$:H = WR(I):WR(I) = WR(J):WR(J) = H
730 NEXT : NEXT
740 REM CALCULATE INITIAL ODDS
750 FOR I = 1 TO 5 STEP 2
760 A = INT(WR(I) *10):B = INT(WR(I +1) *10)
770 GOSUB 1600
780 ODDS(I,1) = B:ODDS(I,2) = A
790 ODDS(I +1,1) = A:ODDS(I +1,2) = B
800 NEXT
810 REM CLEAR OLD BETS
820 FOR I = 1 TO 6:B(I,1) = 0:B(I,2) = 0: NEXT
825 REM CLEAR OLD SCORES
827 FOR I = 1 TO 7:SC(I) = 0: NEXT
830 REM PRINT THE DISPLAY
840 HOME
850 PRINT "SEVERAL CLERICS ARE MADLY SCRIBBLING AT A BLACKBOARD OUTSIDE THE WRESTLING ROOM.AT THIS MOMENT IT READS:"
860 PRINT
870 T1 = 20:T2 = 35
880 PRINT "WRESTLERS"; TAB( T1);"ODDS"; TAB( T2 -2);"SCORE"
890 PRINT
900 FOR I = 1 TO 5 STEP 2
910 PRINT I;". ";WR$(I); TAB( T1);ODDS(I,1);" TO ";ODDS(I,2); TAB( T2);0
920 PRINT I +1;". ";WR$(I +1); TAB( T1);ODDS(I +1,1);" TO ";ODDS(I +1,2); TAB( T2);0
930 PRINT
940 NEXT
950 PRINT "THE WRESTLERS ARE FIGHTING NOW!"
960 PRINT
970 PRINT "(HIT ANY KEY TO PLACE A BET.)"
980 POKE -16368,0
990 REM READ THE KEYBOARD.
1000 I = 1
1010 IF PEEK( -16384) >127 GOTO 1340
1020 I = I +1: IF I < = 100 GOTO 1010
1030 REM FIGHTERS FIGHT.
1040 Z9 = 0: VTAB 7
1050 FOR I = 1 TO 5 STEP 2
1060 IF SC(I) = 10 OR SC(I +1) = 10 THEN : PRINT : PRINT : PRINT : GOTO 1140
1070 Z9 = 1: REM THE FIGHTS ARE STILL IN PROGRESS
1080 IF RND(1) < = WR(I) THEN :SC(I) = SC(I) +1
1090 IF RND(1) < = WR(I +1) THEN :SC(I +1) = SC(I +1) +1
1100 IF SC(I) = 10 AND SC(I +1) = 10 THEN :SC(I) = 9:SC(I +1) = 9: GOTO 1080: REM NO TIE SCORES ALLOWED.
1110 HTAB T2: PRINT SC(I)
1120 HTAB T2: PRINT SC(I +1)
1130 PRINT
1140 NEXT
1150 REM RE-CALCULATE ODDS.
1160 Z9 = 0
1170 VTAB 7
1180 FOR I = 1 TO 5 STEP 2
1190 IF SC(I) = 10 OR SC(I +1) = 10 THEN : HTAB T1: PRINT " ": HTAB T1: PRINT " ": GOTO 1280
1200 Z9 = 1
1210 A = INT(WR(I +1) *(10 -SC(I)) *10)
1220 B = INT(WR(I) *(10 -SC(I +1)) *10)
1230 GOSUB 1600
1240 ODDS(I,1) = A:ODDS(I,2) = B
1250 ODDS(I +1,1) = B:ODDS(I +1,2) = A
1260 HTAB T1: PRINT A;" TO ";B;" "
1270 HTAB T1: PRINT B;" TO ";A;" "
1280 PRINT
1290 NEXT
1300 IF NOT Z9 GOTO 1510: REM END OF FIGHTS
1310 REM GO BACK TO READ KEYBOARD
1320 GOTO 1000
1330 REM RECEIVE A BET
1340 POKE -16368,0
1350 VTAB 20
1360 INPUT "HOW MUCH TO BET? ";BET
1370 IF BET < > INT(BET) GOTO 1350
1380 IF BET >GOLD THEN : PRINT "YOU DON'T HAVE THAT MUCH GOLD!": PRINT "(HIT ANY KEY TO CONTINUE.)": GET R$: PRINT : GOTO 1480
1390 IF BET = 0 GOTO 1480
1400 GOLD = GOLD -BET
1410 VTAB 20: CALL -958
1420 INPUT "BETTING ON WHICH WRESTLER (1-6)? ";NUM
1430 IF NUM <1 OR NUM >6 OR NUM < > INT(NUM) GOTO 1410
1440 IF SC(NUM) = 10 OR (NUM/2 = INT(NUM/2) AND SC(NUM -1) = 10) OR (NUM/2 < > INT(NUM/2) AND SC(NUM +1) = 10) THEN : PRINT "THAT MATCH IS OVER!": PRINT "(HIT ANY KEY TO CONTINUE.)": GET R$: VTAB 22: PRINT : GOTO 1480
1445 VTAB 6: FOR I = 1 TO NUM: PRINT : NEXT : IF NUM >2 THEN PRINT : IF NUM >4 THEN PRINT
1447 INVERSE : HTAB 5: PRINT WR$(NUM): NORMAL
1450 B(NUM,1) = B(NUM,1) + INT(BET *ODDS(NUM,1)/ODDS(NUM,2)) +BET
1460 B(NUM,2) = BET: REM COL. 1 IS WIN, COL. 2 IS LOSE.
1470 POKE -16368,0
1480 VTAB 20: CALL -958
1490 GOTO 1000
1500 REM END OF FIGHTS
1510 VTAB 16: CALL -958
1520 FOR I = 1 TO 6
1530 IF B(I,1) = 0 GOTO 1560
1540 IF SC(I) = 10 THEN : PRINT "YOU WON ";B(I,1) -B(I,2);" GOLD PIECES BETTING": PRINT "ON ";WR$(I);".":GOLD = GOLD +B(I,1): GOTO 1560
1550 PRINT "YOU LOST ";B(I,2);" GOLD PIECES BETTING": PRINT "ON ";WR$(I);"."
1560 NEXT
1570 PRINT "(HIT ANY KEY TO CONTINUE)";: GET R$: PRINT
1580 GOTO 100
1590 REM SUBROUTINE TO REDUCE ODDS
1600 C = 1
1610 P = PRIME(C)
1620 IF P >A OR P >B THEN : RETURN
1630 IF A/P = INT(A/P) AND B/P = INT(B/P) THEN :A = A/P:B = B/P: GOTO 1630
1640 C = C +1: IF C >20 THEN RETURN
1650 GOTO 1610
5000 FM$(17) = STR$(GOLD)
5005 PRINT
5010 PRINT D$"OPEN FRESH MEAT"
5020 PRINT D$"WRITE FRESH MEAT"
5030 FOR I = 1 TO 39: PRINT FM$(I): NEXT
5040 PRINT D$"CLOSE"
5050 PRINT D$"RUN LOBBY"
Text found in Eamon_075_Temple_of_the_Guild_1991_Doumakes_D..do/TEMPLE OF THE GUILD.bas:
1 REM TEMPLE OF THE GUILD
10 D$ = CHR$(4)
20 HOME
30 INVERSE
35 HTAB 10
40 PRINT "TEMPLE OF THE GUILD"
50 NORMAL
60 PRINT : PRINT
70 PRINT " THE JOURNEY TO THE TEMPLE OF THE GUILD OF FREE ADVENTURERS IS LONG AND BORING. THE LOCATION WAS DELIBERATELY CHOSEN FOR ITS REMOTENESS, TO DISCOURAGEYOUNG INEXPERIENCED ADVENTURERS WHO ARE TOO BIG FOR THEIR BRITCHES."
80 PRINT
90 PRINT " AT THE TEMPLE, YOU CAN GET AS INVOLVED OR AS UNINVOLVED AS YOU PLEASE IN A VARIETY OF ATTRACTIONS. YOU MAY LEAVE THE TEMPLE WITH PERMANENTLY ELEVATED HARDINESS, AGILITY, OR"
100 PRINT "CHARISMA, FOR EXAMPLE. PERHAPS YOU WILLCHOOSE A NEW NAME. THERE ARE OPPOR- TUNITIES TO WIN GOLD, AND SEVERAL WAYS TO SPEND OR LOSE IT. THERE ARE ALSO A FEW WAYS TO GET KILLED."
110 PRINT
120 PRINT "(HIT ANY KEY TO CONTINUE.)";
130 GET R$: PRINT : HOME
140 PRINT D$"RUN LOBBY"
- Addeddate
- 2014-06-12 21:27:36
- Emulator
- apple2e
- Emulator_ext
- do
- Identifier
- a2_Eamon_075_Temple_of_the_Guild_1991_Doumakes_D.
- Scanner
- Internet Archive Python library 0.6.5
comment
Reviews
176 Views
DOWNLOAD OPTIONS
IN COLLECTIONS
The Apple II Library: Games The Software Library: Apple Computer Software Library The Emulation StationUploaded by Jason Scott on